{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    kutu.url = "git+https://git.syedm.dev/syedm/kutu.rb.git";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      kutu,
      nixpkgs,
      home-manager,
      ...
    }:
    let
      system = "x86_64-linux";
      commonModules = [
        ./hosts/common.nix
        home-manager.nixosModules.home-manager
        {
          home-manager.users.me = import ./home/common.nix;
          home-manager.users.root = import ./home/root.nix;
        }
      ];
      pkgs = import nixpkgs {
        inherit system;
      };
    in
    {
      nixosConfigurations = {
        syedm = nixpkgs.lib.nixosSystem {
          inherit system;
          modules = commonModules ++ [
            ./hosts/syedm
          ];
        };

        tardis = nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = { inherit kutu; };
          modules = commonModules ++ [
            ./hosts/tardis
            { home-manager.users.me = import ./home/tardis.nix; }
          ];
        };
      };

      # For development
      devShells.${system}.default = pkgs.mkShell {
        packages = with pkgs; [
          nixd
          nixfmt

          lua-language-server
          stylua
        ];
      };
    };
}